Mostrando entradas con la etiqueta Visual Basic Net. Mostrar todas las entradas
Mostrando entradas con la etiqueta Visual Basic Net. Mostrar todas las entradas

Configurar tamaño de papel - hoja personalizada en Crystal Report

Problema: Tengo un reporte creado en Crystal Report con un tamaño de papel personalizado, pero al momento de imprimir, sale con otro tamaño de hoja, por más que el reporte haya sido creado correctamente.
Solución: Por código, configurar el tamaño del papel.
La mayoría de la veces, cuando se crea un reporte, con un tamaño de hoja personalizado, éste se configura correctamente al momento de diseñarlo, pero existen ocasiones, en que por más que dibujemos todo a la perfección, en el rato de la verdad, la hoja toma otro tamaño, siendo imposible imprimir.
Hay que entender que Crystal Report toma la configuración de la impresora predeterminada al momento de mostrar un reporte o imprimirlo, pero algunas veces hace falta más que tener la impresora a punto para que el reporte funcione correctamente.
Aquí se deben tener en cuenta dos cosas: Primero, tener a la mano el nombre de la impresora; ésto es importante porque ya no vamos a usar la impresora predeterminada, se tiene que utilizar un nombre fijo, por lo que si no pueden saberlo por ustedes mismos, deben crear la opción en dónde se deberá obtener de alguna manera el nombre de la impresora. Segundo, tener también a la mano el nombre del papel personalizado; ésto debe ser más sencillo de obtener, puesto que bajo ese tipo de hoja fue creado el reporte, pero si no lo tienen, deberán obtenerlo de alguna manera.
Ahora viene el código.
Voy a utiliza un procedimiento genérico, en donde configuro el reporte.
Private Sub Configurar_Hoja_CrystalReport()
    'Se obtiene el informe a configurar            
    Dim rdInforme As New rptInforme

    'Obtener nombre de impresora
    Dim print_name As String = "Impresora"
    'Obtener nombre de hoja personalizada
    Dim print_paper As String = "HojaPersonalizada"

    'Opciones del Crystal Report
    Dim repOptions As CrystalDecisions.CrystalReports.Engine.PrintOptions
    'Se aplican al informe
    With rdInforme
 'Se obtienen la opciones de impresion
 repOptions = .PrintOptions
 'Se setean las opciones
 With repOptions
     'Obtiene el id del papel --> utiliza una función especial
     .PaperSize = GetPapersizeID(print_name, print_paper)
     'Señala la impresora a utilizar
     .PrinterName = print_name
 End With
    End With
End Sub

Para que funcione este procedimiento, se debe utilizar la siguiente función.
Public Function GetPapersizeID(ByVal PrinterName As String, ByVal PaperSizeName As String) As Integer
 Dim pdprint As New System.Drawing.Printing.PrintDocument()
        Dim PaperSizeID As Integer = 0
        Dim ppname As String = ""
        pdprint.PrinterSettings.PrinterName = PrinterName
        For i As Integer = 0 To pdprint.PrinterSettings.PaperSizes.Count - 1
            Dim rawKind As Integer
            ppname = PaperSizeName
            If pdprint.PrinterSettings.PaperSizes(i).PaperName = ppname Then
                rawKind = CInt(pdprint.PrinterSettings.PaperSizes(i).RawKind)
                PaperSizeID = rawKind
                Exit For
            End If
        Next
        Return PaperSizeID
End Function

De esta manera, el reporte funciona perfectamente.
Esta opción está probada en Visual Studio 2008 Professional

Limpiar todos los controles de un formulario

Problema: Tengo que "poner en blanco" o limpiar todos los controles que tengo dentro de mi formulario, pero sin mencionarlos uno por uno puesto que son muchos. El principal problema es que los controles a limpiar, por ejemplo unos TextBox, están dentro de contenedores como GroupBox o TabControl.
Solución: Encontré este código buscando por la red, lamentablemente no puedo ponerle autoría porque no puedo accesar a la página.
Se copia el siguiente procedimiento.
    Sub sub_limpiar_campos(ByVal c1 As Control)
        'Limpia todos los controles dentro del control principal (c1)
        'aunque esten dentro de otros controles
        For Each c As Control In c1.Controls
            If TypeOf c Is TextBox Then
                c.Text = "" ' eliminar el texto 
            Else
                sub_limpiar_campos(c)
            End If
            If TypeOf c Is ComboBox Then
                c.Text = "" ' eliminar el texto 
            Else
                sub_limpiar_campos(c)
            End If
            If TypeOf c Is DateTimePicker Then
                c.Text = Date.Today ' Pone la fecha actual 
            Else
                sub_limpiar_campos(c)
            End If
            If (TypeOf (c) Is CheckBox) Then
                CType(c, CheckBox).Checked = False 'Quita el check
            Else
                sub_limpiar_campos(c)
            End If
            If (TypeOf (c) Is RadioButton) Then
                CType(c, RadioButton).Checked = False 'Quita el check
            Else
                sub_limpiar_campos(c)
            End If
        Next
    End Sub

Se lo utiliza de la siguiente manera.
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) _
    Handles Button1.Click, Button2.Click
        'Para limpiar todos los controles dentro del formulario
        'Aunque estén dentro de un TabControl o GroupBox
        sub_limpiar_campos(Me)
    End Sub

Validaciones de transacciones en la base de datos

Problema: Tengo varios SPs que guardan información en la base de datos, pero deseo controlar que si alguno falla, la información de todos los SPs no se guarde.
Solución: Trabajar con la transaccionalidad que trae .Net.
Es obvio que las validaciones para las transacciones de escritura a la base de datos debe hacerse dentro del mismo SP, pero cuando se trabaja con varios SPs en el front-end, es decir, desde la capa del negocio, se debe realizar una validación adicional para controlar cualquier fallo que pudiera suceder desde la aplicación.
En realidad, validar las transacciones es fácil, solo se necesita añadir un SqlTransaction a la conexión que invoca al SP, pero en mi caso, que son varios SPs que realizan muchas escrituras a la base de datos, se debe tener un estricto control de la transaccionalidad.
Un ejemplo.
Tengo los siguientes SPs: sp_ingresar_cabecera, sp_ingresar_detalle, sp_registrar_historial, a los cuales debo mantener la secuencia estricta de grabación, es decir, si falla sp_registrar_historial, no debe grabarse sp_ingresar_cabecera ni sp_ingresar_detalle
Esto se logra realizando una opción general, que invoque a los 3 SPs y manteniendo la transacción dentro del mismo.
Private Sub Grabar()
 Using connection As SqlConnection = New SqlConnection(args)
  connection.Open() 'Abre la conexion
  Dim transaction As SqlTransaction 'Crea una variable de transaccion
  transaction = connection.BeginTransaction() 'Inicia la transaccion
  
  'Paso a la funcion la transaccion y la conexion
  if sp_ingresar_cabecera(transaction, connection) = False Then 
   transaction.Rollback() 'Si existe un error en la funcion que graba en el SP, se reversa la transaccion.
   Exit Sub
  End If
  if sp_ingresar_detalle(transaction, connection) = False Then 
   transaction.Rollback() 
   Exit Sub
  End If
  if sp_ingresar_detalle(transaction, connection) = False Then 
   transaction.Rollback() 
   Exit Sub
  End If
  
  transaction.Commit() 'Si todo esta correcto, la transaccion se graba en la base de datos.
  connection.Close()
 End Using
End Sub

Notese que las funciones que se llaman igual a los SPs de grabación se les envía como parámetro la transacción y la conexión, ésto sirve para que no se cree una conexion nueva en cada SP sino que se utilice la misma para todos los SPs, ayudando a que si existe una falla, todos los SPs se reversen.
Para probar que la transaccionalidad está funcionando se puede realizar el siguiente ejemplo.
En Microsoft Visual Studio, en modo de depuración, poner un punto de interrupción en alguno de los SPs que graban información, en el momento en que la información debería estar en la base de datos, como en la linea command.ExecuteNonQuery() o adapter.Fill(DataTable), o simplemente antes de la línea transaction.Commit()
Luego realizar una consulta a la base de datos en el motor de su preferencia, en mi caso es SQL Server y para ello utilizo el Microsoft SQL Server Management Studio y realizo un select sencillo a cualquiera de las tablas que estoy afectando directamente con el SP del Visual Studio.
Si la transaccionalidad está correcta, el select no mostrará ningún valor, y en el peor de los casos, la consulta se quedará congelada indefinidamente.
¿Cómo ésto puede ser bueno?, ¡Mi tabla se encuentra bloqueada! ¡No puedo acceder a ella!
Esta es una de las "bellezas" de la transaccionalidad, la tabla se "bloqueará" cuando se encuentre con una sentencia BeginTransaction y se "liberará" cuando se ejecute Rollback o Commit.
Es por eso que la transaccionalidad es una arma de doble filo, ayuda a que las acciones nunca se realicen si hay un problema, pero la tabla se bloquea hasta que la transacción termine.
Como recomendación, solo se debe usar la transaccionalidad en SPs o consultas que realicen modificación de datos, es decir, si hay Insert, Update o Delete, y no se debe utilizar para otras consultas.
La transaccionalidad ayuda a muchos problemas al momento de modificar los datos, porque, como en mi caso, se necesita que todos los datos sean coherentes para que existan en la base de datos, caso contrario, que ninguna información se grabe.

Clases de Linq to Sql con DataGridView

Problema: Necesito mostrar los datos de unas clases en dos grid tipo maestro - detalle.
Solución: Utilizar clases genéricas y enlazarlos a los grid usando Linq.

Las clases genéricas es un nuevo tipo de elemento que viene en Visual Studio. Se lo puede encontrar al dar click en el menú Proyecto y luego en Agregar Nuevo Elemento. En la ventana de Agregar Nuevo Elemento, en la Categoría Datos, se encuentra la plantilla "Clases de LINQ to SQL", el cual crea un archivo con la extensión .dbml.

Al cargar este archivo aparecerá un apartado en blanco en donde se podrán ir diseñando las clases con sus propiedades, como quien añade tablas y campos. Dos clases se pueden relacionar por medio de una asociación o por herencia, pero realmente se puede controlar el detalle por medio de sentencias Linq.

Para entender un poco mejor, pongo un ejemplo.

Tengo un contenedor de clases llamado DataClasses1DataContext, el cual contiene dentro dos clases "tipadas" llamadas Class1 y Class2. La clase Class1 tiene dos propiedades Property1 (tipo Integer) y Property2 (tipo String), y la clase Class2 tiene tres propiedades Property1 (tipo Integer), Property2 (tipo Integer) y Property3 (tipo String).
Tengo un formulario llamado Form1, el cual contiene dos grid llamados DataGridView1 y DataGridView2.

El código que se utiliza en el formulario principal es el siguiente.

Public Class Form1
    Private Class1 As New List(Of Class1)
    Private Class2 As New List(Of Class2)

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Se llenan los datos
        llenar_clase1()
        llenar_clase2()

        'Se asignan los datos al grid
        DataGridView1.DataSource = Class1
        'Para que se seleccione toda la fila
        DataGridView1.SelectionMode = DataGridViewSelectionMode.FullRowSelect

        'Se obtiene la primera fila del grid principal y se lo setea
        'al grid detalle por medio de linq
        Dim Clase2 = From clase In Class2 Where clase.Property2 = 1
        Dim clases2 = Clase2.ToList
        DataGridView2.DataSource = clases2
    End Sub

    Private Sub llenar_clase1()
        'Aqui se debe utilizar una funcion para llenar los datos
        'Esta funcion se llena con datos de prueba
        Dim dt_table As New DataTable
        dt_table = dt_clase1()

        'Recorremos los datos temporales para llenar la clase
        For Each dt As DataRow In dt_table.Rows
            'Se crea una instancia nueva de la clase 
            'para llenarlo en la lista
            Dim clase1 As Class1 = New Class1

            'Se pasan los datos
            clase1.Property1 = dt.Item("col1")
            clase1.Property2 = dt.Item("col2")

            'Se llena la lista principal
            Class1.Add(clase1)
        Next
    End Sub

    Private Function dt_clase1() As DataTable
        Dim new_DataTable As New DataTable

        'Creando las columnas
        new_DataTable.Columns.Add("col1")
        new_DataTable.Columns.Add("col2")

        'Crando las filas o datos
        new_DataTable.Rows.Add(1, "AAA")
        new_DataTable.Rows.Add(2, "BBB")
        new_DataTable.Rows.Add(3, "CCC")

        dt_clase1 = new_DataTable
    End Function

    Private Sub llenar_clase2()
        'Aqui se debe utilizar una funcion para llenar los datos
        'Esta funcion se llena con datos de prueba
        Dim dt_table As New DataTable
        dt_table = dt_clase2()

        'Recorremos los datos temporales para llenar la clase
        For Each dt As DataRow In dt_table.Rows
            'Se crea una instancia nueva de la clase 
            'para llenarlo en la lista
            Dim clase2 As Class2 = New Class2

            'Se pasan los datos
            clase2.Property1 = dt.Item("col1")
            clase2.Property2 = dt.Item("col2")
            clase2.Property3 = dt.Item("col3")

            'Se llena la lista principal
            Class2.Add(clase2)
        Next
    End Sub

    Private Function dt_clase2() As DataTable
        Dim new_DataTable As New DataTable

        'Creando las columnas
        new_DataTable.Columns.Add("col1")
        new_DataTable.Columns.Add("col2")
        new_DataTable.Columns.Add("col3")

        'Crando las filas o datos
        new_DataTable.Rows.Add(1, 1, "AAA-AAA")
        new_DataTable.Rows.Add(1, 2, "AAA-BBB")
        new_DataTable.Rows.Add(1, 3, "AAA-CCC")
        new_DataTable.Rows.Add(2, 1, "BBB-AAA")
        new_DataTable.Rows.Add(2, 2, "BBB-BBB")
        new_DataTable.Rows.Add(2, 3, "BBB-CCC")
        new_DataTable.Rows.Add(3, 1, "CCC-AAA")
        new_DataTable.Rows.Add(3, 2, "CCC-BBB")
        new_DataTable.Rows.Add(3, 3, "CCC-CCC")

        dt_clase2 = new_DataTable
    End Function

    Private Sub DataGridView1_CellClick(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewCellEventArgs) _
    Handles DataGridView1.CellClick
        'Cada vez que cambie de fila, se actualiza el grid de detalle
        Dim Clase2 = From clase In Class2 Where clase.Property2 = e.RowIndex + 1
        Dim clases2 = Clase2.ToList
        DataGridView2.DataSource = clases2
    End Sub
End Class

El Linq es parecido a las sentencias de SQL y se basan en la misma lógica, pero no en el mismo orden.

Una sentencia Linq es parecido a lo siguiente.

Dim valor = From variable In contenedor Where variable = objeto Select variable

valor es el resultado y lo que contiene la sentencia devuelta.
variable es una temporal en donde se procesará la setencia dependiendo de la condición.
contenedor es la clase o el objeto que pueda utilizar una sentencia Linq.
objeto es la restricción que se necesita para obtener un conjunto determinado de datos.

Quienes hayan usado sentencias SQL podrán fácilmente adaptarse al Linq.

Usar clases genéricas o tipadas es muy útil y versatil, sobre todo cuando se necesita trabajar con diferentes fuentes de datos y/o no se puede utilizar los orígenes estándares como DataTables o DataSets.

Su poder se ve apreciado cuando se tiene enlazados más de un maestro - detalle, o se cuenta con una cadena de detalles. Por ejemplo, una cotización que tiene varias facturas y cada factura tiene su cabecera y detalle, esta complejidad se ahorra mucho tiempo de código al "dibujar" las clases y relacionarlas entre sí, siendo el Linq el que facilita la tarea del filtrado de los datos.

Obtener peso de una balanza por medio de un puerto serial Comm1

Problema: Tengo una balanza conectada a mi computadora, por medio del puerto serial Comm1, a la cual le debo capturar el peso para grabarlo en su respectivo registo.
Solución: Verificar que la balanza esté conectada y programar la función que obtenga el peso.

Primero, antes de ponerse a programar, estar totalmente seguros que existe conexión entre la balanza y la computadora, que la balanza esté enviando correctamente los datos, además de que la computadora los esté recibiendo.

Para ello se utiliza el programa Hyper Terminal, que suele venir en Windows XP.

En la pantalla del Hyper Terminal se puede ver que los datos de la balanza no son fijos, al menos en mi caso, sino que constantemente está enviando información si cesar, no solo del peso, sino de muchos datos adicionales.

En mi caso, la información está dividida por comas, que debo tener en cuenta al momento de programar.

Ya entrando de lleno a la programación, al cargar la aplicación, valido que el puerto esté abierto y que se esté recibiendo información de la balanza, ésto lo hago con el siguiente procedimiento.

Private Sub captura_puerto2()
        Dim num_puerto As Integer
        Dim returnStr As String = ""

        On Error GoTo fallo
        num_puerto = 1
 
 'Variable global
        nombre_puerto = "COM" & num_puerto

        Using com1 As IO.Ports.SerialPort = My.Computer.Ports.OpenSerialPort(nombre_puerto)
            com1.DataBits = 8
            com1.ReadTimeout = 3600
            Dim Incoming As String = com1.ReadLine()
            returnStr = Incoming
            Thread.Sleep(100)
            Incoming = com1.ReadLine()
            com1.Close()
        End Using

        Exit Sub
fallo:
        MsgBox(Err.Description, vbCritical)
End Sub

Luego, para capturar el peso, el cual lo hago desde un grid, cuando presionan Enter, utilizo lo siguiente.

Private Sub DataGridView1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) _
Handles DataGridView1.KeyDown
 If DataGridView1.CurrentCell.ColumnIndex = 1 Then 'Columna que se captura el peso
  DataGridView1.CurrentCell.Value = fp_captura_peso()
 End If
End Sub

Private Function fp_captura_peso() As Double
        Dim lnLen As Long
        Dim lnCRpos As Object
        Dim InBuffer As Object
        Dim InMiddle, InDistinct As Object
        Dim peso_final As Object = 0
        Dim n As Long
        On Error GoTo fallo
        lcEntrada = " "
        fp_captura_peso = 0

        Using com1 As IO.Ports.SerialPort = My.Computer.Ports.OpenSerialPort(nombre_puerto)
            Dim Incoming As String = com1.ReadLine()
            Thread.Sleep(100)
            Incoming = com1.ReadLine()
            lcEntrada = Incoming
        End Using

        If Len(Trim(lcEntrada)) > 10 Then
            Dim subStrings() As String
            Dim TestArray() As String = Split(lcEntrada, ",")

            For i As Integer = 0 To TestArray.Length - 1
                If TestArray(i) <> "" Then
                    If Char.IsNumber(Trim(TestArray(i))) = True Then
                        peso_final = TestArray(i)
                    End If
                End If
            Next

            If IsNumeric(peso_final) Then
                If peso_final >= 0 Then
                    fp_captura_peso = Format(CDbl(peso_final), "###,##0.0000")
                    Exit Function
                End If
            Else
                fp_captura_peso = 0
            End If
        Else
            MsgBox("No se ha detectado peso, intente nuevamente...", vbCritical)
        End If

        Exit Function

fallo:
        MsgBox(Err.Description)
End Function

Para que funcione correctamente se debe importar la siguiente librería.

Imports MSCommLib

Mostrando un cuadro de dialogo de confirmación cuando el usuario intenta eliminar una fila de un grid DataGridView

Problema: Tengo un grid con datos, pero antes de que el usuario elimine una fila, necesito que confirme si realmente desea borrarla o solo fue un descuido con el teclado.
Solución: Utilizando correctamente el evento UserDeletingRow.

El evento UserDeletingRow se ejecuta después de que el usuario presionó la tecla Supr y antes de que la fila desaparezca completamente del grid.

Para mayor entendimiento, pongo un ejemplo.

Tengo un formulario llamado Form1, el cual contiene un grid llamado DataGridView1.

Lo siguiente es lo que va en el evento UserDeletingRow.

Private Sub DataGridView1_UserDeletingRow(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewRowCancelEventArgs) _
Handles DataGridView1.UserDeletingRow
        If Not e.Row.IsNewRow Then 'Se verifica que no sea una nueva fila
            Dim response As DialogResult = MessageBox.Show("¿Está seguro?", "¿Borrar fila?", MessageBoxButtons.YesNo, _
                                                           MessageBoxIcon.Question, MessageBoxDefaultButton.Button2)
            If response = DialogResult.No Then
                e.Cancel = True
            End If
        End If
End Sub

Dos grid DataGridView en relación maestro - detalle

Problema: Tengo dos grid, donde el primero muestra los datos maestros principales, y el segundo grid, debe cambiar los datos, dependiendo de la fila seleccionada del maestro, con el detalle respectivo.

Solución: Utilizar la habilidad de relación de un dataset.

Para explicar mejor, pongo un ejemplo.

Tengo mi formulario llamado Form1, el cual contiene dos grid, GridMaestro y GridDetalle.

Todo la programación lo realizo en el load del formulario.

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Creo un dataset que va a contener las tablas maestro - detalle
        Dim ds As New DataSet

        'Creo los binding que relacionen a los grid
        Dim maestroBinding As New BindingSource
        Dim detalleBinding As New BindingSource

        'Creo la tabla maestro y lo lleno con datos
        Dim tablaMaestro As DataTable = ds.Tables.Add("tablaMaestro")
        tablaMaestro.Columns.Add("unico")
        tablaMaestro.Columns.Add("dato")
        tablaMaestro.Rows.Add(1, "AAA")
        tablaMaestro.Rows.Add(2, "BBB")
        tablaMaestro.Rows.Add(3, "CCC")

        'Creo el grid detalle y lo lleno con datos
        Dim tablaDetalle As DataTable = ds.Tables.Add("tablaDetalle")
        tablaDetalle.Columns.Add("unico")
        tablaDetalle.Columns.Add("relacion")
        tablaDetalle.Columns.Add("dato")
        tablaDetalle.Rows.Add(1, 1, "AAA-AAA")
        tablaDetalle.Rows.Add(2, 1, "BBB-AAA")
        tablaDetalle.Rows.Add(3, 1, "CCC-AAA")
        tablaDetalle.Rows.Add(1, 2, "AAA-BBB")
        tablaDetalle.Rows.Add(2, 2, "BBB-BBB")
        tablaDetalle.Rows.Add(3, 2, "CCC-BBB")
        tablaDetalle.Rows.Add(1, 3, "AAA-CCC")
        tablaDetalle.Rows.Add(2, 3, "BBB-CCC")
        tablaDetalle.Rows.Add(3, 3, "CCC-CCC")

        'Creo la relacion entre las dos tablas
        Dim columnaMaestro As DataColumn = tablaMaestro.Columns(0)
        Dim columnaDetalle As DataColumn = tablaDetalle.Columns(1)
        Dim relation As DataRelation
        relation = New DataRelation("relacion", columnaMaestro, columnaDetalle)

        'Asigno la relacion al dataset
        ds.Relations.Add(relation)

        'Relaciono el Binding Maestro al dataset
        maestroBinding.DataSource = ds
        maestroBinding.DataMember = "tablaMaestro"

        'Asigno el binding del maestro al detalle e identifico la relacion
        detalleBinding.DataSource = maestroBinding
        detalleBinding.DataMember = "relacion"

        'Asigno los grid a los binding
        GridMaestro.DataSource = maestroBinding
        GridDetalle.DataSource = detalleBinding
End Sub

La belleza aquí es la relación asignada al detalleBinding, el cual hace que al cambiar las filas en el maestro, se actualice la información en el detalle.

Mostrar datos de un grid (DataGridView) de una columna combo box (DataGridViewComboBoxCell) basados en la selección de otra columna combo box

Problema: Tengo un grid, el cual tiene dos columnas de tipo combo box, en donde, dependiendo de lo que el usuario seleccione en la primera columna combo box, debe presentarse los datos en la segunda columna combo box.
Solución: Crear una nueva celda tipo combo box y reemplazarlo por el original.

Sabemos que antes de llenar el grid con los datos, debemos primero llenar los datos de la columna combo box, y luego, pasar los datos al grid, caso contrario nos dará un bonito error de que el combo box no está relacionado con nuestros datos.

Pero cuando tenemos datos de tipo grupo - subgrupo, en donde dependiendo del grupo cambia la información del subgrupo, se debe crear un mecanismo para que, a la hora de editar la información, la segunda columna combo box, cambie con respecto a la selección de la primera.

Existen muchas maneras de hacerlo, sobre todo dependiendo de cómo se esté obteniendo la información y cómo se estén enlazando los datos al combo box.

Se puede encontrar mucha información en la red sobre la manera de realizar este mismo proceso, algunos indican que la manera más práctica es traer toda la información en la segunda columna combo box y filtarlo dependiendo de lo seleccionado.

En mi caso, que la información es demasiado extensa para traerla toda y ponerla dentro de la segunda columna del combo box, he decidido volver a traer la información desde la base de datos con lo seleccionado en el primer combo box y llenar el segundo combo box con la resultante. Esto también sirve de ayuda para que, dependiendo de los datos de una tercera y/o cuarta columna, también se deba realizar el filtro correspondiente.

Para que se entienda mejor mi explicación, voy a poner un poco de código de ejemplo.

Tengo un formulario llamado Form1, el cual contiene un grid llamado DataGridView1, el cual a su vez, tiene dos columnas combo box llamadas dtg_cmb1 y dtg_cmb2

La acción que se dispara al momento en que el usuario selecciona un dato del primer combo box es el CellValueChanged, por lo que iniciaré por allí.

Private Sub DataGridView1_CellValueChanged(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewCellEventArgs) _
Handles DataGridView1.CellValueChanged
 Dim r As Integer = e.RowIndex
 Dim c As Integer = e.ColumnIndex
 Dim dgrow As New DataGridViewComboBoxCell()
 
 Select Case c
         Case 1 'Pregunto si la columna seleccionada pertenece al primer combo box
          'Aquí realizo el llenado de los datos, dependiendo de lo seleccionado
          Using connection As SqlConnection = New SqlConnection(conn)
           Dim command As New SqlCommand("sp_datos_combobox", connection)
           command.CommandType = CommandType.StoredProcedure
           Dim adapter As New SqlDataAdapter(command)
           With command.Parameters
            .Add(New SqlParameter("@param1", SqlDbType.Int)).Value = DataGridView1.Rows(r).Cells("dtg_cmb1").Value
           End With
           Dim dataCombo As New DataTable
           adapter.Fill(dataCombo)
           'Aqui enlazo los datos al combo box
           dgrow.DataSource = dataCombo
           dgrow.DisplayMember = "campo1"
           dgrow.ValueMember = "campo2"
           
           'Aqui cambio el combo box original, por lo obtenido de la consulta
           DataGridView1.Item("dtg_cmb2", DataGridView1.CurrentCell.RowIndex) = dgrow
          End Using
 End Select
End Sub

Mostrando varios encabezados de columnas combinados en un DataGridView

Problema: Deseo tener, como en Microsoft Excel, un encabezado doble en dos columnas que estén combinados.

De esta manera.

------------------------------------------------------
|     Enero          |       Febrero         |     Marzo          |
|  Ganó | Perdió |  Ganó   | Perdió   |  Ganó | Perdió  |
------------------------------------------------------
|           |            |             |              |            |             |
|           |            |             |              |            |             |
------------------------------------------------------

Solución: Se debe personalizar el evento Paint.

Para mayor entendimiento, pongo un ejemplo.

Tengo un formulario llamado Form1, el cual contiene un grid llamado DataGridView1.

En el evento load del formulario lleno el grid.

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Lleno los datos del grid
        With DataGridView1
            .Columns.Add("", "Ganó")
            .Columns.Add("", "Perdió")
            .Columns.Add("", "Ganó")
            .Columns.Add("", "Perdió")
            .Columns.Add("", "Ganó")
            .Columns.Add("", "Perdió")

            .ColumnHeadersHeightSizeMode = DataGridViewColumnHeadersHeightSizeMode.EnableResizing
            .ColumnHeadersHeight = .ColumnHeadersHeight * 2
            .ColumnHeadersDefaultCellStyle.Alignment = DataGridViewContentAlignment.BottomCenter
        End With
    End Sub

Luego, se personaliza el evento Paint del DataGridView.

    Private Sub dataGridView1_Paint(ByVal sender As System.Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles DataGridView1.Paint
        Dim monthes As String() = {"Enero", "Febrero", "Marzo"}

        Dim j As Integer = 0
        While j < 6
            Dim r1 As Rectangle = Me.DataGridView1.GetCellDisplayRectangle(j, -1, True)
            r1.X += 1
            r1.Y += 1
            r1.Width = r1.Width * 2 - 2
            r1.Height = r1.Height / 2 - 2

            e.Graphics.FillRectangle(New SolidBrush(Me.DataGridView1.ColumnHeadersDefaultCellStyle.BackColor), r1)

            Dim format As New StringFormat()

            format.Alignment = StringAlignment.Center
            format.LineAlignment = StringAlignment.Center
            e.Graphics.DrawString(monthes(j \ 2), Me.DataGridView1.ColumnHeadersDefaultCellStyle.Font, _
                                  New SolidBrush(Me.DataGridView1.ColumnHeadersDefaultCellStyle.ForeColor), r1, format)
            j += 2
        End While
    End Sub

Nota: Ejemplos e información proporcionada desde está página web: Windows Forms Data Controls and Databinding FAQ

Cambiando dinámicamente, por programación, el tipo de celda DataGridViewCell de un DataGridView

Problema: Tengo un grid que contiene una columna de tipo combo DataGridViewComboBoxCell y deseo que, por medio de programación, cambiarlo a un tipo texto DataGridViewTextBoxCell, pero solo una celda en particular.
Solución: Crear un nuevo tipo y asignarlo al grid.

Para mejor comprensión, pongo un ejemplo.

Tengo un formulario llamado Form1, el cual contiene un grid llamado DataGridView1 y un botón llamado Button1.

En el load del formulario tengo el llenado del grid.

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        'Se llenan datos de prueba en el grid
        Dim dt As New DataTable("b")
        dt.Columns.Add("col")
        dt.Rows.Add("bb1")
        dt.Rows.Add("bb2")
        dt.Rows.Add("bb3")
        Me.DataGridView1.DataSource = dt

        'Se crea una columna combo, se llenan de datos de prueba y se añade al grid
        Dim cmb As New DataGridViewComboBoxColumn()
        cmb.Items.Add("111")
        cmb.Items.Add("222")
        cmb.Items.Add("333")
        Me.DataGridView1.Columns.Add(cmb)
End Sub

Luego, el cambio de tipo lo tengo en el evento Click del botón.

Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim cell As New DataGridViewTextBoxCell() 'Creamos un nuevo tipo de celda
        cell.Value = "bb1" 'Se pone un valor cualquiera
        Me.DataGridView1(1, 1) = cell 'Se lo cambia en la posicion deseada
End Sub

Nota: Ejemplos e información proporcionada desde está página web: Windows Forms Data Controls and Databinding FAQ

Mostrando un texto vertical en la celda de un DataGridView

Problema: Necesito que el texto de una celda se muestre de manera vertical.
Solución: Se debe controlar el evento CellPainting del DataGridView.

Para entenderlo mejor, pongo un ejemplo a continuación.

Tengo un formulario llamado Form1, el cual contiene un grid llamado DataGridView1.

En el load del formulario tengo el llenado del grid.

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
 'Se llenan datos de prueba en el grid
 Dim dt As New DataTable()
 dt.Columns.Add("c1")
 dt.Columns.Add("c2")

 For j As Integer = 0 To 9
  dt.Rows.Add("aaaaaaaaa", "bbbb") 'Son datos cualquiera de prueba
 Next

 Me.DataGridView1.DataSource = dt

 For j As Integer = 0 To 9
  Dim height As Integer = TextRenderer.MeasureText(Me.DataGridView1(0, j).Value.ToString(), _
           Me.DataGridView1.DefaultCellStyle.Font).Width
      Me.DataGridView1.Rows(j).Height = height
 Next

 AddHandler DataGridView1.CellPainting, AddressOf dataGridView1_CellPainting 'Aqui se invoca al evento CellPainting
End Sub

Después se programa la parte del CellPainting.

No se utiliza la que viene por defecto en el Visual. Esto es copiar y pegar.

Private Sub dataGridView1_CellPainting(ByVal sender As Object, ByVal e As DataGridViewCellPaintingEventArgs)
 If e.ColumnIndex = 0 AndAlso e.RowIndex > -1 AndAlso e.Value IsNot Nothing Then
         e.Paint(e.CellBounds, DataGridViewPaintParts.All And Not DataGridViewPaintParts.ContentForeground)

             Dim sf As New StringFormat()

             sf.Alignment = StringAlignment.Center
             sf.LineAlignment = StringAlignment.Center
             sf.FormatFlags = StringFormatFlags.DirectionVertical 'Aqui le indico que sea vertical

             e.Graphics.DrawString(e.Value.ToString(), e.CellStyle.Font, New SolidBrush(e.CellStyle.ForeColor), e.CellBounds, sf)

             e.Handled = True
        End If
End Sub

Nota: Ejemplos e información proporcionada desde está página web: Windows Forms Data Controls and Databinding FAQ